Edit detail for SandBox Quaternion Algebra is Frobenius in Many Ways revision 8 of 32

Quaternion Algebra Is Frobenius In Many Ways

Linear operators over a 4-dimensional vector space representing quaternion algebra

Ref:

• http://arxiv.org/abs/1103.5113

  -permuted Frobenius Algebras

  Zbigniew Oziewicz (UNAM), Gregory Peter Wene (UTSA)

• http://mat.uab.es/~kock/TQFT.html

  Frobenius algebras and 2D topological quantum field theories

  Joachim Kock

• http://en.wikipedia.org/wiki/Frobenius_algebra

We need the Axiom LinearOperator? library.

)library MONAL PROP LIN CALEY

   Monoidal is now explicitly exposed in frame initial 
   Monoidal will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/MONAL.NRLIB/MONAL
   Prop is now explicitly exposed in frame initial 
   Prop will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/PROP.NRLIB/PROP
   LinearOperator is now explicitly exposed in frame initial 
   LinearOperator will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/LIN.NRLIB/LIN
   CaleyDickson is now explicitly exposed in frame initial 
   CaleyDickson will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CALEY.NRLIB/CALEY

Use the following macros for convenient notation

-- summation
macro Σ(x,i,n)==reduce(+,[x for i in n])

-- list
macro Ξ(f,i,n)==[f for i in n]

-- subscript
macro sb == subscript

𝐋 is the domain of 4-dimensional linear operators over the rational functions ℚ (Expression Integer), i.e. ratio of polynomials with integer coefficients.

dim:=4

(1)

macro ℒ == List

macro ℂ == CaleyDickson

macro ℚ == Expression Integer

𝐋 := LinearOperator(dim, OVAR [], ℚ)

(2)

𝐞:ℒ 𝐋      := basisVectors()

(3)

𝐝:ℒ 𝐋      := basisForms()

(4)

o:𝐋:=1     -- identity for product

(5)

I:𝐋:=[1]   -- identity for composition

(6)

X:𝐋:=[2,1] -- twist

(7)

Now generate structure constants for Quaternion Algebra

The basis consists of the real and imaginary units. We use quaternion multiplication to form the "multiplication table" as a matrix. Then the structure constants can be obtained by dividing each matrix entry by the list of basis vectors.

Split-complex and co-quaternions can be specified by Caley-Dickson parameters (q0 = -1, q1 = -1)

--q0:=sb('q,[0])
q0:=1  -- not split-complex

(8)

q1:=sb('q,[1])

(9)

--q1:=1  -- co-quaternion
QQ := ℂ(ℂ(ℚ,'i,q0),'j,q1);

Basis: Each B.i is a quaternion number

B:ℒ QQ := map(x +-> hyper x,1$SQMATRIX(dim,ℚ)::ℒ ℒ ℚ)

(10)

-- Multiplication table:
M:Matrix QQ := matrix Ξ(Ξ(B.i*B.j, i,1..dim), j,1..dim)

(11)

-- Function to divide the matrix entries by a basis element
S(y) == map(x +-> real real(x/y),M)

-- The result is a nested list
ѕ :=map(S,B)::ℒ ℒ ℒ ℚ

Compiling function S with type CaleyDickson(CaleyDickson(Expression(
      Integer),i,1),j,*01q(1)) -> Matrix(Expression(Integer))

(12)

-- structure constants form a tensor operator
Y := Σ(Σ(Σ(ѕ(i)(k)(j)*𝐞.i*𝐝.j*𝐝.k, i,1..dim), j,1..dim), k,1..dim)

(13)

arity Y

(14)

matrix Ξ(Ξ((𝐞.i*𝐞.j)/Y, i,1..dim), j,1..dim)

(15)

Multiplication of arbitrary quaternions and

a:=Σ(sb('a,[i])*𝐞.i, i,1..dim)

(16)

b:=Σ(sb('b,[i])*𝐞.i, i,1..dim)

(17)

(a*b)/Y

(18)

A scalar product is denoted by the (2,0)-tensor

U:=inp([inp([script('u,[[j,i],[]]) for i in 1..dim])$𝐋 for j in 1..dim])$𝐋

(19)

Definition 1

We say that the scalar product is associative if the tensor equation holds:

    Y   =   Y
     U     U

In other words, if the (3,0)-tensor:

(20)

Using the LinearOperator? domain in Axiom and some carefully chosen symbols we can easily enter expressions that are both readable and interpreted by Axiom as "graphical calculus" diagrams describing complex products and compositions of linear operators.

ω:𝐋 :=
     o    Y I      /
     o     U       -
     o    I Y      /
     o     U       o

(21)

Note: The only purpose of the o symbols on the left above is to serve as a constant left-side margin as required by Axiom. The symbols on the right describe the relation between row.

Definition 2

An algebra with a non-degenerate associative scalar product is called a [Frobenius Algebra]?.

We may consider the problem where multiplication Y is given, and look for all associative scalar products

This problem can be solved using linear algebra.

)expose MCALCFN

   MultiVariableCalculusFunctions is now explicitly exposed in frame 
      initial 
J := jacobian(ravel ω,concat map(variables,ravel U)::ℒ Symbol);

u := transpose matrix [concat map(variables,ravel U)::ℒ Symbol];

J::OutputForm * u::OutputForm = 0

(22)

nrows(J),ncols(J)

(23)

The matrix J transforms the coefficients of the tensor into coefficients of the tensor . We are looking for the general linear family of tensors such that J transforms into for any such .

If the null space of the J matrix is not empty we can use the basis to find all non-trivial solutions for U:

Ñ:=nullSpace(J)

(24)

ℰ:=map((x,y)+->x=y, concat
       map(variables,ravel U), entries Σ(sb('p,[i])*Ñ.i, i,1..#Ñ) )

(25)

This defines a family of pre-Frobenius algebras:

zero? eval(ω,ℰ)

(26)

In general the pairing is not symmetric!

Ų:𝐋 := eval(U,ℰ)

(27)

matrix Ξ(Ξ((𝐞.i 𝐞.j)/Ų, i,1..dim), j,1..dim)

(28)

This is the most general form of the "dot product" of two quaternions

(a*b)/Ų

(29)

(a*a)/Ų

(30)

The scalar product must be non-degenerate:

Ů:=determinant Ξ(Ξ(retract((𝐞.i * 𝐞.j)/Ų), j,1..dim), i,1..dim)

(31)

factor Ů

(32)

Definition 3

Co-pairing

Ω:𝐋:=unravel((0/2)$Prop,concat(transpose(1/Ů*adjoint([[retract((𝐞.i * 𝐞.j)/Ų)
  for j in 1..dim] for i in 1..dim]).adjMat)::ℒ ℒ ℚ))

(33)

matrix Ξ(Ξ(Ω/(𝐝.i*𝐝.j), i,1..dim), j,1..dim)

(34)

Check dimension

d:𝐋:=
    o   Ω    /
    o   Ų    o

(35)

Definition 4

Co-algebra:

    λ:𝐋 :=
         o    Ω Ω  I    /
         o   I Y I I    /
         o   I  X  I    /
         o   I I  Ų     o
    --test

Why aren't these the same?? Left and Right co-algebras because quaternions are not commutative?

λ:𝐋 :=
     o    I Ω     /
     o     Y I    o

(36)

λr:𝐋 :=
     o     Ω I    /
     o    I Y     o

(37)

λ - λr

(38)

i = Unit of the algebra

i:=𝐞.1

(39)

test
     o    i     /
     o    λ     =    Ω

(40)

test
     o    i     /
     o    λr    =    Ω

(41)

Handle(s)

Hl:𝐋 :=
     o    λ    o /
     o    Y    o

(42)

Hr:𝐋 :=
     o    λr   o /
     o    Y    o

(43)

Hl - Hr

(44)

Definition 5

  i 
  U
  

ι:𝐋:=
    o    i I    /
    o     Ų    o

(45)

Y=U
ι  

test
   o     Y     /
   o     ι     o  = Ų

(46)

For example:

ex1:=[p[1]=0,p[2]=0,p[3]=0,p[4]=1]

(47)

Ų0:𝐋  :=eval(Ų,ex1)

(48)

Ω0:𝐋  :=eval(Ω,ex1)$𝐋

(49)

λ0:𝐋  :=eval(λ,ex1)$𝐋

(50)

λr0:𝐋 :=eval(λr,ex1)$𝐋

(51)

test(λ0=λr0)

(52)

Hl0:𝐋 :=eval(Hl,ex1)$𝐋

(53)

Hr0:𝐋 :=eval(Hr,ex1)$𝐋

(54)

test(Hl0=Hr0)

(55)