Edit detail for SandBox Quaternion Algebra is Frobenius in Many Ways revision 15 of 32

Quaternion Algebra Is Frobenius In Many Ways

Linear operators over a 4-dimensional vector space representing quaternion algebra

Ref:

• http://arxiv.org/abs/1103.5113

  -permuted Frobenius Algebras

  Zbigniew Oziewicz (UNAM), Gregory Peter Wene (UTSA)

• http://mat.uab.es/~kock/TQFT.html

  Frobenius algebras and 2D topological quantum field theories

  Joachim Kock

• http://en.wikipedia.org/wiki/Frobenius_algebra

We need the Axiom LinearOperator? library.

)library CARTEN ARITY CMONAL CPROP CLOP CALEY

   CartesianTensor is now explicitly exposed in frame initial 
   CartesianTensor will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CARTEN.NRLIB/CARTEN
   Arity is now explicitly exposed in frame initial 
   Arity will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/ARITY.NRLIB/ARITY
   ClosedMonoidal is now explicitly exposed in frame initial 
   ClosedMonoidal will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CMONAL.NRLIB/CMONAL
   ClosedProp is now explicitly exposed in frame initial 
   ClosedProp will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CPROP.NRLIB/CPROP
   ClosedLinearOperator is now explicitly exposed in frame initial 
   ClosedLinearOperator will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CLOP.NRLIB/CLOP
   CaleyDickson is now explicitly exposed in frame initial 
   CaleyDickson will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CALEY.NRLIB/CALEY

Use the following macros for convenient notation

-- summation
macro Σ(x,i,n)==reduce(+,[x for i in n])

-- list
macro Ξ(f,i,n)==[f for i in n]

-- subscript
macro sb == subscript

𝐋 is the domain of 4-dimensional linear operators over the rational functions ℚ (Expression Integer), i.e. ratio of polynomials with integer coefficients.

dim:=4

(1)

macro ℒ == List

macro ℂ == CaleyDickson

macro ℚ == Expression Integer

𝐋 := ClosedLinearOperator(OVAR ['1,'i,'j,'k], ℚ)

(2)

𝐞:ℒ 𝐋      := basisOut()

(3)

𝐝:ℒ 𝐋      := basisIn()

(4)

I:𝐋:=[1]   -- identity for composition

(5)

X:𝐋:=[2,1] -- twist

(6)

V:𝐋:=ev(1) -- evaluation

(7)

Λ:𝐋:=co(1) -- co-evaluation

(8)

Now generate structure constants for Quaternion Algebra

The basis consists of the real and imaginary units. We use quaternion multiplication to form the "multiplication table" as a matrix. Then the structure constants can be obtained by dividing each matrix entry by the list of basis vectors.

Split-complex and co-quaternions can be specified by Caley-Dickson parameters (q0 = -1, q1 = -1)

--q0:=sb('q,[0])
q0:=1  -- not split-complex

(9)

q1:=sb('q,[1])

(10)

--q1:=1  -- co-quaternion
QQ := ℂ(ℂ(ℚ,'i,q0),'j,q1);

Basis: Each B.i is a quaternion number

B:ℒ QQ := map(x +-> hyper x,1$SQMATRIX(dim,ℚ)::ℒ ℒ ℚ)

(11)

-- Multiplication table:
M:Matrix QQ := matrix Ξ(Ξ(B.i*B.j, i,1..dim), j,1..dim)

(12)

-- Function to divide the matrix entries by a basis element
S(y) == map(x +-> real real(x/y),M)

-- The result is a nested list
ѕ :=map(S,B)::ℒ ℒ ℒ ℚ

Compiling function S with type CaleyDickson(CaleyDickson(Expression(
      Integer),i,1),j,*01q(1)) -> Matrix(Expression(Integer))

(13)

-- structure constants form a tensor operator
Y := Σ(Σ(Σ(ѕ(i)(k)(j)*𝐞.i*𝐝.j*𝐝.k, i,1..dim), j,1..dim), k,1..dim)

(14)

arity Y

(15)

matrix Ξ(Ξ((𝐞.i*𝐞.j)/Y, i,1..dim), j,1..dim)

(16)

Multiplication of arbitrary quaternions and

a:=Σ(sb('a,[i])*𝐞.i, i,1..dim)

(17)

b:=Σ(sb('b,[i])*𝐞.i, i,1..dim)

(18)

(a*b)/Y

(19)

Cartan-Killing Trace Form

( I I   ) / _
(  Y Λ  ) / _
(   Y I ) / _
     V

(20)

A scalar product is denoted by the (2,0)-tensor

U:=Σ(Σ(script('u,[[],[i,j]])*𝐝.i*𝐝.j, i,1..dim), j,1..dim)

(21)

Definition 1

We say that the scalar product is associative if the tensor equation holds:

    Y   =   Y
     U     U

In other words, if the (3,0)-tensor:

(22)

Using the LinearOperator? domain in Axiom and some carefully chosen symbols we can easily enter expressions that are both readable and interpreted by Axiom as "graphical calculus" diagrams describing complex products and compositions of linear operators.

ω:𝐋 :=
     (    Y I    )  /
           U        -
     (    I Y    )  /
           U

(23)

Definition 2

An algebra with a non-degenerate associative scalar product is called a [Frobenius Algebra]?.

We may consider the problem where multiplication Y is given, and look for all associative scalar products

This problem can be solved using linear algebra.

)expose MCALCFN

   MultiVariableCalculusFunctions is now explicitly exposed in frame 
      initial 
J := jacobian(ravel ω,concat map(variables,ravel U)::ℒ Symbol);

u := transpose matrix [concat map(variables,ravel U)::ℒ Symbol];

J::OutputForm * u::OutputForm = 0

(24)

nrows(J),ncols(J)

(25)

The matrix J transforms the coefficients of the tensor into coefficients of the tensor . We are looking for the general linear family of tensors such that J transforms into for any such .

If the null space of the J matrix is not empty we can use the basis to find all non-trivial solutions for U:

Ñ:=nullSpace(J)

(26)

ℰ:=map((x,y)+->x=y, concat
       map(variables,ravel U), entries Σ(sb('p,[i])*Ñ.i, i,1..#Ñ) )

(27)

This defines a family of pre-Frobenius algebras:

zero? eval(ω,ℰ)

(28)

In general the pairing is not symmetric!

Ų:𝐋 := eval(U,ℰ)

(29)

matrix Ξ(Ξ((𝐞.i 𝐞.j)/Ų, i,1..dim), j,1..dim)

(30)

This is the most general form of the "dot product" of two quaternions

(a*b)/Ų

(31)

(a*a)/Ų

(32)

The scalar product must be non-degenerate:

Ů:=determinant Ξ(Ξ(retract((𝐞.i * 𝐞.j)/Ų), j,1..dim), i,1..dim)

(33)

factor Ů

(34)

Definition 3

Co-pairing

Solve the [Snake Relation]? as a system of linear equations.

Ω:𝐋:=Σ(Σ(script('u,[[i,j]])*𝐞.i*𝐞.j, i,1..dim), j,1..dim)

(35)

d1:=(I*Ω)/(Ų*I);

d2:=(Ω*I)/(I*Ų);

equate(f,g)==map((x,y)+->(x=y),ravel f, ravel g);

eq1:=equate(d1,I);

Compiling function equate with type (ClosedLinearOperator(
      OrderedVariableList([1,i,j,k]),Expression(Integer)),
      ClosedLinearOperator(OrderedVariableList([1,i,j,k]),Expression(
      Integer))) -> List(Equation(Expression(Integer)))

eq2:=equate(d2,I);

snake:=solve(concat(eq1,eq2),concat Ξ(Ξ(script('u,[[i,j]]), i,1..dim), j,1..dim));

if #snake ~= 1 then error "no solution"

Ω:=eval(Ω,snake(1))

(36)

matrix Ξ(Ξ(Ω/(𝐝.i*𝐝.j), i,1..dim), j,1..dim)

(37)

Check "dimension" and the snake relations.

d:𝐋:=
       Ω    /
       X    /
       Ų

(38)

test
    (    I Ω     )  /
    (     Ų I    )  =  I

(39)

test
    (     Ω I    )  /
    (    I Ų     )  =  I

(40)

Definition 4

Co-algebra

Compute the "three-point" function and use it to define co-multiplication.

W:=(Y,I)/Ų

(41)

λ:=(Ω,I,Ω)/(I,W,I)

(42)

test
     (    I Ω     )  /
     (     Y I    )  =  λ

(43)

test
     (     Ω I    )  /
     (    I Y     )  =  λ

(44)

Frobenius Condition

Χ :=
         Y    /
         λ

(45)

test
     (   λ I   )  /
     (  I Y    )  =  Χ

(46)

test
     (   I λ   )  /
     (    Y I  )  =  Χ

(47)

i = Unit of the algebra

i:=𝐞.1

(48)

test
         i     /
         λ     =    Ω

(49)

Handle

H:𝐋 :=
         λ     /
         X     /
         Y

(50)

Definition 5

  i 
  U
  

ι:𝐋:=
    (    i I   ) /
          Ų

(51)

Y=U
ι  

test
        Y     /
        ι     =  Ų

(52)

For example:

ex1:=[q[1]=1,p[1]=1,p[2]=1,p[3]=1,p[4]=1]

(53)

Ų0:𝐋  :=eval(Ų,ex1)

(54)

Ω0:𝐋  :=eval(Ω,ex1)$𝐋

(55)

λ0:𝐋  :=eval(λ,ex1)$𝐋

(56)

H0:𝐋 :=eval(H,ex1)$𝐋

(57)