Edit detail for SandBox Quaternion Algebra is Frobenius in Many Ways revision 28 of 32

Quaternion Algebra Is Frobenius In Many Ways

Linear operators over a 4-dimensional vector space representing quaternion algebra

Ref:

• http://arxiv.org/abs/1103.5113

  -permuted Frobenius Algebras

  Zbigniew Oziewicz (UNAM), Gregory Peter Wene (UTSA)

• http://mat.uab.es/~kock/TQFT.html

  Frobenius algebras and 2D topological quantum field theories

  Joachim Kock

• http://en.wikipedia.org/wiki/Frobenius_algebra

We need the Axiom LinearOperator? library.

)library CARTEN ARITY CMONAL CPROP CLOP CALEY

   CartesianTensor is now explicitly exposed in frame initial 
   CartesianTensor will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CARTEN.NRLIB/CARTEN
   Arity is now explicitly exposed in frame initial 
   Arity will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/ARITY.NRLIB/ARITY
   ClosedMonoidal is now explicitly exposed in frame initial 
   ClosedMonoidal will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CMONAL.NRLIB/CMONAL
   ClosedProp is now explicitly exposed in frame initial 
   ClosedProp will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CPROP.NRLIB/CPROP
   ClosedLinearOperator is now explicitly exposed in frame initial 
   ClosedLinearOperator will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CLOP.NRLIB/CLOP
   CaleyDickson is now explicitly exposed in frame initial 
   CaleyDickson will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CALEY.NRLIB/CALEY

Use the following macros for convenient notation

-- summation
macro Σ(x,i,n)==reduce(+,[x for i in n])

-- list
macro Ξ(f,i,n)==[f for i in n]

-- subscript and superscripts
macro sb == subscript

macro sp == superscript

𝐋 is the domain of 4-dimensional linear operators over the rational functions ℚ (Expression Integer), i.e. ratio of polynomials with integer coefficients.

dim:=4

(1)

macro ℒ == List

macro ℂ == CaleyDickson

macro ℚ == Expression Integer

𝐋 := ClosedLinearOperator(OVAR ['1,'i,'j,'k], ℚ)

(2)

𝐞:ℒ 𝐋      := basisOut()

(3)

𝐝:ℒ 𝐋      := basisIn()

(4)

I:𝐋:=[1]   -- identity for composition

(5)

X:𝐋:=[2,1] -- twist

(6)

V:𝐋:=ev(1) -- evaluation

(7)

Λ:𝐋:=co(1) -- co-evaluation

(8)

equate(eq)==map((x,y)+->(x=y),ravel lhs eq, ravel rhs eq);

Now generate structure constants for Quaternion Algebra

The basis consists of the real and imaginary units. We use quaternion multiplication to form the "multiplication table" as a matrix. Then the structure constants can be obtained by dividing each matrix entry by the list of basis vectors.

Split-complex and co-quaternions can be specified by Caley-Dickson parameters (i2, j2)

i2:=sp('i,[2])

(9)

--i2:= -1  -- complex
j2:=sp('j,[2])

(10)

--j2:= -1  -- quaternion
QQ := ℂ(ℂ(ℚ,'i,-i2),'j,-j2);

Basis: Each B.i is a quaternion number

B:ℒ QQ := map(x +-> hyper x,1$SQMATRIX(dim,ℚ)::ℒ ℒ ℚ)

(11)

-- Multiplication table:
M:Matrix QQ := matrix Ξ(Ξ(B.i*B.j, i,1..dim), j,1..dim)

(12)

-- Function to divide the matrix entries by a basis element
S(y) == map(x +-> real real(x/y),M)

-- The result is a nested list
ѕ :=map(S,B)::ℒ ℒ ℒ ℚ

Compiling function S with type CaleyDickson(CaleyDickson(Expression(
      Integer),i,-(*001i(2))),j,-(*001j(2))) -> Matrix(Expression(
      Integer))

(13)

-- structure constants form a tensor operator
Y := Σ(Σ(Σ(ѕ(i)(k)(j)*𝐞.i*𝐝.j*𝐝.k, i,1..dim), j,1..dim), k,1..dim)

(14)

arity Y

(15)

matrix Ξ(Ξ((𝐞.i*𝐞.j)/Y, i,1..dim), j,1..dim)

(16)

Multiplication of arbitrary quaternions and

a:=Σ(sb('a,[i])*𝐞.i, i,1..dim)

(17)

b:=Σ(sb('b,[i])*𝐞.i, i,1..dim)

(18)

(a*b)/Y

(19)

Multiplication is Associative

test(
  ( I Y ) / _
  (  Y  ) = _
  ( Y I ) / _
  (  Y  ) )

(20)

A scalar product is denoted by the (2,0)-tensor

U:=Σ(Σ(script('u,[[],[i,j]])*𝐝.i*𝐝.j, i,1..dim), j,1..dim)

(21)

Definition 1

We say that the scalar product is associative if the tensor equation holds:

    Y   =   Y
     U     U

In other words, if the (3,0)-tensor:

(22)

Using the LinearOperator? domain in Axiom and some carefully chosen symbols we can easily enter expressions that are both readable and interpreted by Axiom as "graphical calculus" diagrams describing complex products and compositions of linear operators.

ω:𝐋 :=
     (    Y I    )  /
           U        -
     (    I Y    )  /
           U

(23)

Definition 2

An algebra with a non-degenerate associative scalar product is called a [Frobenius Algebra]?.

The Cartan-Killing Trace

Ú:=
   (  Y Λ  ) / _
   (   Y I ) / _
        V

(24)

Ù:=
   (  Λ Y  ) / _
   ( I Y   ) / _
      V

(25)

test(Ù=Ú)

(26)

forms a non-degenerate associative scalar product for Y

Ũ := Ù

(27)

test
     (    Y I    )  /
           Ũ        =
     (    I Y    )  /
           Ũ

(28)

determinant Ξ(Ξ(retract((𝐞.i * 𝐞.j)/Ũ), j,1..dim), i,1..dim)

(29)

General Solution

We may consider the problem where multiplication Y is given, and look for all associative scalar products

This problem can be solved using linear algebra.

)expose MCALCFN

   MultiVariableCalculusFunctions is now explicitly exposed in frame 
      initial 
J := jacobian(ravel ω,concat map(variables,ravel U)::ℒ Symbol);

u := transpose matrix [concat map(variables,ravel U)::ℒ Symbol];

J::OutputForm * u::OutputForm = 0

(30)

nrows(J),ncols(J)

(31)

The matrix J transforms the coefficients of the tensor into coefficients of the tensor . We are looking for the general linear family of tensors such that J transforms into for any such .

If the null space of the J matrix is not empty we can use the basis to find all non-trivial solutions for U:

Ñ:=nullSpace(J)

(32)

ℰ:=map((x,y)+->x=y, concat
       map(variables,ravel U), entries Σ(sb('p,[i])*Ñ.i, i,1..#Ñ) )

(33)

This defines a family of pre-Frobenius algebras:

zero? eval(ω,ℰ)

(34)

In general the pairing is not symmetric!

Ų:𝐋 := eval(U,ℰ)

(35)

u1:=matrix Ξ(Ξ((𝐞.i 𝐞.j)/Ų, i,1..dim), j,1..dim)

(36)

This is the most general form of the "dot product" of two quaternions

(a*b)/Ų

(37)

(a*a)/Ų

(38)

Cartan-Killing is a special case

ck:=solve(equate(Ũ=Ų),Ξ(sb('p,[i]), i,1..#Ñ)).1

Compiling function equate with type Equation(ClosedLinearOperator(
      OrderedVariableList([1,i,j,k]),Expression(Integer))) -> List(
      Equation(Expression(Integer)))

(39)

The scalar product must be non-degenerate:

Ů:=determinant Ξ(Ξ(retract((𝐞.i * 𝐞.j)/Ų), j,1..dim), i,1..dim)

(40)

factor(numer Ů)/factor(denom Ů)

(41)

Definition 3

Co-scalar product (pairing)

Solve the [Snake Relation]? as a system of linear equations.

Ω:𝐋:=Σ(Σ(script('u,[[i,j]])*𝐞.i*𝐞.j, i,1..dim), j,1..dim)

(42)

ΩX:=Ω/X;

--d1:=(I*Ω)/(Ų*I);
--d2:=(Ω*I)/(I*Ų);
UXΩ:=(I*ΩX)/(Ų*I);

ΩXU:=(ΩX*I)/(I*Ų);

eq1:=equate(UXΩ=I);

eq2:=equate(ΩXU=I);

snake:=solve(concat(eq1,eq2),concat Ξ(Ξ(script('u,[[i,j]]), i,1..dim), j,1..dim));

if #snake ~= 1 then error "no solution"

Ω:=eval(Ω,snake(1))

(43)

ΩX:=Ω/X;

matrix Ξ(Ξ(Ω/(𝐝.i*𝐝.j), i,1..dim), j,1..dim)

(44)

Check "dimension" and the snake relations.

d:𝐋:=
       Ω    /
       Ų

(45)

test
    (    I ΩX     )  /
    (     Ų I     )  =  I

(46)

test
    (     ΩX I    )  /
    (    I Ų      )  =  I

(47)

Cartan-Killing co-scalar

eval(Ω,ck)

(48)

Definition 4

Co-algebra

Compute the "three-point" function and use it to define co-multiplication.

W:=
  (Y I) /
    Ų

(49)

λ:=
  (  ΩX I ΩX  ) /
  (  I  W  I  )

(50)

Cartan-Killing co-multiplication

eval(λ,ck)

(51)

test
     (    I ΩX     )  /
     (     Y I     )  =  λ

(52)

test
     (     ΩX I    )  /
     (    I  Y     )  =  λ

(53)

Co-associativity

test(
  (  λ  ) / _
  ( I λ ) = _
  (  λ  ) / _
  ( λ I ) )

(54)

Frobenius Condition (fork)

H :=
         Y    /
         λ

(55)

test
     (   λ I   )  /
     (  I Y    )  =  H

(56)

test
     (   I λ   )  /
     (    Y I  )  =  H

(57)

The Cartan-Killing form makes H of the Frobenius condition idempotent

test( eval(H,ck)=eval(H/H,ck) )

(58)

But it is not unique. E.g. other idempots

h1:=map(numer,ravel(H-H/H)::List FRAC POLY INT);

h2:=groebner h1

(59)

ck3:=[p[1]=1,p[2]=1,p[3]=1,i2=-1,j2=-1]

(60)

ck4:=solve(eval(h2,ck3),[p[4]])

(61)

test( eval(H,concat(ck3,ck4.1))=eval(H/H,concat(ck3,ck4.1)) )

(62)

test( eval(H,concat(ck3,ck4.2))=eval(H/H,concat(ck3,ck4.2)) )

(63)

determinant Ξ(Ξ(retract( (𝐞.i * 𝐞.j)/eval(Ų,concat(ck3,ck4.1)) ), j,1..dim), i,1..dim)

(64)

determinant Ξ(Ξ(retract( (𝐞.i * 𝐞.j)/eval(Ų,concat(ck3,ck4.2)) ), j,1..dim), i,1..dim)

(65)

Handle

Φ :=
         λ     /
         Y

(66)

The Cartan-Killing form makes Φ of the identity

test( eval(Φ,ck)=I )

(67)

but it can be the identity in many ways. For example,

solve(equate(eval(Φ,[p[1]=1,p[2]=1,p[3]=1,j2=-1])=I),[p[4]])

(68)

If handle is identity then fork is idempotent but the converse is not true

Φ1:=map(numer,ravel(Φ-I)::List FRAC POLY INT);

Φ2:=groebner Φ1

(69)

in?(ideal h2, ideal Φ2)

(70)

in?(ideal Φ2, ideal h2)

(71)

Definition 5

Unit

e:=𝐞.1

(72)

test
         e     /
         λ     =    ΩX

(73)

Co-unit

d:=
    (    e I   ) /
          Ų

(74)

test
        Y     /
        d     =  Ų

(75)

Figure 12

φφ:=          _
  ( Ω  Ω  ) / _
  ( X I I ) / _
  ( I X I ) / _
  ( I I X ) / _
  (  Y  Y );

φφ1:=map((x:ℚ):ℚ+->numer x,φφ)

(76)

φφ2:=denom(ravel(φφ).1)

(77)

test(φφ=(1/φφ2)*φφ1)

(78)

For Cartan-Killing this is just the co-scalar

test(eval(φφ,ck)=eval(Ω,ck))

(79)

test(eval((e,e)/H,ck)=eval(Ω,ck))

(80)

Bi-algebra conditions

ΦΦ:=          _
  (  λ λ  ) / _
  ( I I X ) / _
  ( I X I ) / _
  ( I I X ) / _
  (  Y  Y ) ;

test((e,e)/ΦΦ=φφ)

(81)

test(eval(ΦΦ,ck)=eval(H,ck))

(82)

test(eval(ΦΦ/(d,d),ck)=Ũ)

(83)

test(eval(H/(d,d),ck)=Ũ)

(84)

Theorem 8.3

i:=𝐞.2; j:=𝐞.3; k:=𝐞.4; k2:=-i2*j2;

u2:=matrix [ _
        [e/d,     i/d,    j/d,     k/d], _
        [i/d,  i2*e/d,    k/d,  i2*j/d], _
        [j/d,    -k/d, j2*e/d, -j2*i/d], _
        [k/d, -i2*j/d, j2*i/d, k2*e/d]]

(85)

test(u2=transpose(u1))

(86)

Ů2 := -retract( k2*(e/d)^2 + j2*(i/d)^2 + i2*(j/d)^2 - (k/d)^2 )^2

(87)

factor(numer Ů2)/factor(denom Ů2)

(88)

test(Ů=Ů2)

(89)