Edit detail for The Algebra of Complex Numbers Is Frobenius In Many Ways revision 2 of 11

The Algebra of Complex Numbers Is Frobenius In Many Ways

Linear operators over a 2-dimensional vector space representing the algebra of complex numbers

Ref:

• http://arxiv.org/abs/1103.5113

  -permuted Frobenius Algebras

  Zbigniew Oziewicz (UNAM), Gregory Peter Wene (UTSA)

• http://mat.uab.es/~kock/TQFT.html

  Frobenius algebras and 2D topological quantum field theories

  Joachim Kock

• http://en.wikipedia.org/wiki/Frobenius_algebra

We need the Axiom LinearOperator? library.

)library CARTEN MONAL PROP LOP CALEY

   CartesianTensor is now explicitly exposed in frame initial 
   CartesianTensor will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CARTEN.NRLIB/CARTEN
   Monoidal is now explicitly exposed in frame initial 
   Monoidal will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/MONAL.NRLIB/MONAL
   Prop is now explicitly exposed in frame initial 
   Prop will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/PROP.NRLIB/PROP
   LinearOperator is now explicitly exposed in frame initial 
   LinearOperator will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/LOP.NRLIB/LOP
   CaleyDickson is now explicitly exposed in frame initial 
   CaleyDickson will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CALEY.NRLIB/CALEY

Use the following macros for convenient notation

-- summation
macro Σ(x,i,n)==reduce(+,[x for i in n])

-- list
macro Ξ(f,i,n)==[f for i in n]

-- subscript
macro sb == subscript

𝐋 is the domain of 2-dimensional linear operators over the rational functions ℚ (Expression Integer), i.e. ratio of polynomials with integer coefficients.

dim:=2

(1)

macro ℒ == List

macro ℂ == CaleyDickson

macro ℚ == Expression Integer

𝐋 := LinearOperator(OVAR ['1,'2], ℚ)

(2)

𝐞:ℒ 𝐋      := basisOut()

(3)

𝐝:ℒ 𝐋      := basisIn()

(4)

I:𝐋:=[1]   -- identity for composition

(5)

X:𝐋:=[2,1] -- twist

(6)

Now generate structure constants for Quaternion Algebra

The basis consists of the real and imaginary units. We use quaternion multiplication to form the "multiplication table" as a matrix. Then the structure constants can be obtained by dividing each matrix entry by the list of basis vectors.

Split-complex can be specified by Caley-Dickson parameter (q0 = -1)

q0:=sb('q,[0])

(7)

--q0:=1  -- split-complex
QQ := ℂ(ℚ,'i,q0);

Basis: Each B.i is a quaternion number

B:ℒ QQ := map(x +-> hyper x,1$SQMATRIX(dim,ℚ)::ℒ ℒ ℚ)

(8)

-- Multiplication table:
M:Matrix QQ := matrix Ξ(Ξ(B.i*B.j, i,1..dim), j,1..dim)

(9)

-- Function to divide the matrix entries by a basis element
S(y) == map(x +-> real(x/y),M)

-- The result is a nested list
ѕ :=map(S,B)::ℒ ℒ ℒ ℚ

Compiling function S with type CaleyDickson(Expression(Integer),i,
      *01q(0)) -> Matrix(Expression(Integer))

(10)

-- structure constants form a tensor operator
Y := Σ(Σ(Σ(ѕ(i)(k)(j)*𝐞.i*𝐝.j*𝐝.k, i,1..dim), j,1..dim), k,1..dim)

(11)

arity Y

(12)

matrix Ξ(Ξ((𝐞.i*𝐞.j)/Y, i,1..dim), j,1..dim)

(13)

Multiplication of arbitrary quaternions and

a:=Σ(sb('a,[i])*𝐞.i, i,1..dim)

(14)

b:=Σ(sb('b,[i])*𝐞.i, i,1..dim)

(15)

(a*b)/Y

(16)

A scalar product is denoted by the (2,0)-tensor

U:=Σ(Σ(script('u,[[],[i,j]])*𝐝.i*𝐝.j, i,1..dim), j,1..dim)

(17)

Definition 1

We say that the scalar product is associative if the tensor equation holds:

    Y   =   Y
     U     U

In other words, if the (3,0)-tensor:

(18)

Using the LinearOperator? domain in Axiom and some carefully chosen symbols we can easily enter expressions that are both readable and interpreted by Axiom as "graphical calculus" diagrams describing complex products and compositions of linear operators.

ω:𝐋 :=
     (    Y I    ) /
           U       -
     (    I Y    ) /
           U

(19)

Definition 2

An algebra with a non-degenerate associative scalar product is called a [Frobenius Algebra]?.

We may consider the problem where multiplication Y is given, and look for all associative scalar products

This problem can be solved using linear algebra.

)expose MCALCFN

   MultiVariableCalculusFunctions is now explicitly exposed in frame 
      initial 
J := jacobian(ravel ω,concat map(variables,ravel U)::ℒ Symbol);

u := transpose matrix [concat map(variables,ravel U)::ℒ Symbol];

J::OutputForm * u::OutputForm = 0

(20)

nrows(J),ncols(J)

(21)

The matrix J transforms the coefficients of the tensor into coefficients of the tensor . We are looking for the general linear family of tensors such that J transforms into for any such .

If the null space of the J matrix is not empty we can use the basis to find all non-trivial solutions for U:

Ñ:=nullSpace(J)

(22)

ℰ:=map((x,y)+->x=y, concat
       map(variables,ravel U), entries Σ(sb('p,[i])*Ñ.i, i,1..#Ñ) )

(23)

This defines a family of pre-Frobenius algebras:

zero? eval(ω,ℰ)

(24)

In two dimensions the pairing is necessarily symmetric!

Ų:𝐋 := eval(U,ℰ)

(25)

matrix Ξ(Ξ((𝐞.i 𝐞.j)/Ų, i,1..dim), j,1..dim)

(26)

This is the most general form of the "dot product" of two complex numbers

(a*b)/Ų

(27)

(a*a)/Ų

(28)

The scalar product must be non-degenerate:

Ů:=determinant Ξ(Ξ(retract((𝐞.i * 𝐞.j)/Ų), j,1..dim), i,1..dim)

(29)

factor Ů

(30)

Definition 3

Co-pairing

Solve the [Snake Relation]? as a system of linear equations.

Ω:𝐋:=Σ(Σ(script('u,[[i,j]])*𝐞.i*𝐞.j, i,1..dim), j,1..dim)

(31)

d1:=(I*Ω)/(Ų*I);

d2:=(Ω*I)/(I*Ų);

equate(f,g)==map((x,y)+->(x=y),ravel f, ravel g);

eq1:=equate(d1,I);

Compiling function equate with type (LinearOperator(
      OrderedVariableList([1,2]),Expression(Integer)),LinearOperator(
      OrderedVariableList([1,2]),Expression(Integer))) -> List(Equation
      (Expression(Integer)))

eq2:=equate(d2,I);

snake:=solve(concat(eq1,eq2),concat Ξ(Ξ(script('u,[[i,j]]), i,1..dim), j,1..dim));

if #snake ~= 1 then error "no solution"

Ω:=eval(Ω,snake(1))

(32)

matrix Ξ(Ξ(Ω/(𝐝.i*𝐝.j), i,1..dim), j,1..dim)

(33)

Check "dimension" and the snake relations.

d:𝐋:=
       Ω    /
       X    /
       Ų

(34)

test
    (    I Ω     )  /
    (     Ų I    )  =  I

(35)

test
    (     Ω I    )  /
    (    I Ų     )  =  I

(36)

Definition 4

Co-algebra

Compute the "three-point" function and use it to define co-multiplication.

W:=
  (Y,I) /
    Ų

(37)

λ:=
  ( Ω,I,Ω ) /
  (I, W ,I)

(38)

test
     (    I Ω     )  /
     (     Y I    )  =  λ

(39)

test
     (     Ω I    )  /
     (    I Y     )  =  λ

(40)

Frobenius Condition

Χ :=
         Y    /
         λ

(41)

test
     (   λ I   )  /
     (  I Y    )  =  Χ

(42)

test
     (   I λ   )  /
     (    Y I  )  =  Χ

(43)

i = Unit of the algebra

i:=𝐞.1

(44)

test
         i     /
         λ     =    Ω

(45)

Handle

H:𝐋 :=
         λ     /
         X     /
         Y

(46)

Definition 5

  i 
  U
  

ι:𝐋:=
    (   i I   ) /
         Ų

(47)

Y=U
ι  

test
        Y     /
        ι     =  Ų

(48)

For example:

ex1:=[q[0]=1,p[1]=0,p[2]=1]

(49)

Ų0:𝐋  :=eval(Ų,ex1)

(50)

Ω0:𝐋  :=eval(Ω,ex1)$𝐋

(51)

λ0:𝐋  :=eval(λ,ex1)$𝐋

(52)

H0:𝐋 :=eval(H,ex1)$𝐋

(53)