Edit detail for The Algebra of Complex Numbers Is Frobenius In Many Ways revision 10 of 11

The Algebra of Complex Numbers Is Frobenius In Many Ways

Linear operators over a 2-dimensional vector space representing the algebra of complex numbers

Ref:

• http://arxiv.org/abs/1103.5113

  -permuted Frobenius Algebras

  Zbigniew Oziewicz (UNAM), Gregory Peter Wene (UTSA)

• http://mat.uab.es/~kock/TQFT.html

  Frobenius algebras and 2D topological quantum field theories

  Joachim Kock

• http://en.wikipedia.org/wiki/Frobenius_algebra

We need the Axiom LinearOperator? library.

(1) -> )library CARTEN ARITY CMONAL CPROP CLOP CALEY

   CartesianTensor is now explicitly exposed in frame initial 
   CartesianTensor will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CARTEN.NRLIB/CARTEN
   Arity is now explicitly exposed in frame initial 
   Arity will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/ARITY.NRLIB/ARITY
   ClosedMonoidal is now explicitly exposed in frame initial 
   ClosedMonoidal will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CMONAL.NRLIB/CMONAL
   ClosedProp is now explicitly exposed in frame initial 
   ClosedProp will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CPROP.NRLIB/CPROP
   ClosedLinearOperator is now explicitly exposed in frame initial 
   ClosedLinearOperator will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CLOP.NRLIB/CLOP
   CaleyDickson is now explicitly exposed in frame initial 
   CaleyDickson will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CALEY.NRLIB/CALEY

Use the following macros for convenient notation

-- summation
macro Σ(x,i,n)==reduce(+,[x for i in n])

-- list
macro Ξ(f,i,n)==[f for i in n]

-- subscript and superscripts
macro sb == subscript

macro sp == superscript

𝐋 is the domain of 2-dimensional linear operators over the rational functions ℚ (Expression Integer), i.e. ratio of polynomials with integer coefficients.

dim:=2

(1)

macro ℒ == List

macro ℂ == CaleyDickson

macro ℚ == Expression Integer

𝐋 := ClosedLinearOperator(OVAR ['1,'i], ℚ)

(2)

𝐞:ℒ 𝐋      := basisOut()

(3)

𝐝:ℒ 𝐋      := basisIn()

(4)

I:𝐋:=[1]   -- identity for composition

(5)

X:𝐋:=[2,1] -- twist

(6)

V:𝐋:=ev(1) -- evaluation

(7)

Λ:𝐋:=co(1) -- co-evaluation

(8)

equate(eq)==map((x,y)+->(x=y),ravel lhs eq, ravel rhs eq);

Now generate structure constants for Complex Algebra

The basis consists of the real and imaginary units. We use complex multiplication to form the "multiplication table" as a matrix. Then the structure constants can be obtained by dividing each matrix entry by the list of basis vectors.

Split-complex can be specified by Caley-Dickson parameter (i2)

--i2:=sp('i,[2])
i2:= -1  -- complex

(9)

QQ := ℂ(ℚ,'i,-i2);

Basis: Each B.i is a complex number

B:ℒ QQ := map(x +-> hyper x,1$SQMATRIX(dim,ℚ)::ℒ ℒ ℚ)

(10)

-- Multiplication table:
M:Matrix QQ := matrix Ξ(Ξ(B.i*B.j, i,1..dim), j,1..dim)

(11)

-- Function to divide the matrix entries by a basis element
S(y) == map(x +-> real(x/y),M)

-- The result is a nested list
ѕ :=map(S,B)::ℒ ℒ ℒ ℚ

Compiling function S with type CaleyDickson(Expression(Integer),i,1)
       -> Matrix(Expression(Integer))

(12)

-- structure constants form a tensor operator
Y := Σ(Σ(Σ(ѕ(i)(k)(j)*𝐞.i*𝐝.j*𝐝.k, i,1..dim), j,1..dim), k,1..dim)

(13)

arity Y

(14)

matrix Ξ(Ξ((𝐞.i*𝐞.j)/Y, i,1..dim), j,1..dim)

(15)

Units

e:=𝐞.1; i:=𝐞.2;

Multiplication of arbitrary ccomplex numbers and

a:=Σ(sb('a,[i])*𝐞.i, i,1..dim)

(16)

b:=Σ(sb('b,[i])*𝐞.i, i,1..dim)

(17)

(a*b)/Y

(18)

Multiplication is Associative

test(
  ( I Y ) / _
  (  Y  ) = _
  ( Y I ) / _
  (  Y  ) )

(19)

A scalar product is denoted by the (2,0)-tensor

U:=Σ(Σ(script('u,[[],[i,j]])*𝐝.i*𝐝.j, i,1..dim), j,1..dim)

(20)

Definition 1

We say that the scalar product is associative if the tensor equation holds:

    Y   =   Y
     U     U

In other words, if the (3,0)-tensor:

(21)

Using the LinearOperator? domain in Axiom and some carefully chosen symbols we can easily enter expressions that are both readable and interpreted by Axiom as "graphical calculus" diagrams describing complex products and compositions of linear operators.

ω:𝐋 :=
     (    Y I    )  /
           U        -
     (    I Y    )  /
           U

(22)

Definition 2

An algebra with a non-degenerate associative scalar product is called a [Frobenius Algebra]?.

The Cartan-Killing Trace

Ú:=
   (  Y Λ  ) / _
   (   Y I ) / _
        V

(23)

Ù:=
   (  Λ Y  ) / _
   ( I Y   ) / _
      V

(24)

test(Ù=Ú)

(25)

forms a non-degenerate associative scalar product for Y

Ũ := Ù

(26)

test
     (    Y I    )  /
           Ũ        =
     (    I Y    )  /
           Ũ

(27)

determinant Ξ(Ξ(retract((𝐞.i * 𝐞.j)/Ũ), j,1..dim), i,1..dim)

(28)

General Solution

We may consider the problem where multiplication Y is given, and look for all associative scalar products

This problem can be solved using linear algebra.

)expose MCALCFN

   MultiVariableCalculusFunctions is now explicitly exposed in frame 
      initial 
J := jacobian(ravel ω,concat map(variables,ravel U)::ℒ Symbol);

nrows(J),ncols(J)

(29)

The matrix J transforms the coefficients of the tensor into coefficients of the tensor . We are looking for the general linear family of tensors such that J transforms into for any such .

If the null space of the J matrix is not empty we can use the basis to find all non-trivial solutions for U:

Ñ:=nullSpace(J)

(30)

ℰ:=map((x,y)+->x=y, concat
       map(variables,ravel U), entries Σ(sb('p,[i])*Ñ.i, i,1..#Ñ) )

(31)

This defines a family of pre-Frobenius algebras:

zero? eval(ω,ℰ)

(32)

Ų:𝐋 := eval(U,ℰ)

(33)

Frobenius Form (co-unit)

d:=ε1*𝐝.1+εi*𝐝.2

(34)

𝔇:=equate(d=
    (    e I   ) / _
          Ų    )

Compiling function equate with type Equation(ClosedLinearOperator(
      OrderedVariableList([1,i]),Expression(Integer))) -> List(Equation
      (Expression(Integer)))

(35)

Express scalar product in terms of Frobenius form

𝔓:=solve(𝔇,Ξ(sb('p,[i]), i,1..#Ñ)).1

(36)

Ų:=eval(Ų,𝔓)

(37)

test
        Y     /
        d     =  Ų

(38)

In general the pairing is not symmetric!

u1:=matrix Ξ(Ξ(retract((𝐞.i 𝐞.j)/Ų), i,1..dim), j,1..dim)

(39)

The scalar product must be non-degenerate:

Ů:=determinant u1

(40)

factor(numer Ů)/factor(denom Ů)

(41)

Cartan-Killing is a special case

ck:=solve(equate(eval(Ũ,𝔓)=Ų),[ε1,εi]).1

(42)

Frobenius scalar product of complex numbers and

a:=sb('a,[1])*e+sb('a,[2])*i

(43)

b:=sb('b,[1])*e+sb('b,[2])*i

(44)

(a,a)/Ų

(45)

(b,b)/Ų

(46)

ab:=(a,b)/Ų

(47)

solve(equate(ab=0*ab),[sb('b,[1]),sb('b,[2])])

(48)

Definition 3

Co-scalar product

Solve the [Snake Relation]? as a system of linear equations.

Ω:𝐋:=Σ(Σ(script('u,[[i,j]])*𝐞.i*𝐞.j, i,1..dim), j,1..dim)

(49)

ΩX:=Ω/X;

UXΩ:=(I*ΩX)/(Ų*I);

ΩXU:=(ΩX*I)/(I*Ų);

eq1:=equate(UXΩ=I);

eq2:=equate(ΩXU=I);

snake:=solve(concat(eq1,eq2),concat Ξ(Ξ(script('u,[[i,j]]), i,1..dim), j,1..dim));

if #snake ~= 1 then error "no solution"

Ω:=eval(Ω,snake(1))

(50)

ΩX:=Ω/X;

The common demoninator is

squareFreePart factor denom Ů / squareFreePart factor numer Ů

Function:  squareFree : % -> Factored(%) is missing from domain: Factored(SparseMultivariatePolynomial(Integer,Kernel(Expression(Integer))))
   Internal Error
   The function squareFree with signature (Factored $)$ is missing from 
      domain Factored
      (SparseMultivariatePolynomial (Integer) (Kernel (Expression (Integer))))

Check "dimension" and the snake relations.

O:𝐋:=
       Ω    /
       Ų

(51)

test
    (    I ΩX     )  /
    (     Ų I     )  =  I

(52)

test
    (     ΩX I    )  /
    (    I Ų      )  =  I

(53)

Cartan-Killing co-scalar

eval(Ω,ck)

(54)

Definition 4

Co-algebra

Compute the "three-point" function and use it to define co-multiplication.

W:=
  (Y I) /
    Ų

(55)

λ:=
  (  ΩX I ΩX  ) /
  (  I  W  I  )

(56)

Cartan-Killing co-multiplication

eval(λ,ck)

(57)

test
     (    I ΩX     )  /
     (     Y I     )  =  λ

(58)

test
     (     ΩX I    )  /
     (    I  Y     )  =  λ

(59)

Co-associativity

test(
  (  λ  ) / _
  ( I λ ) = _
  (  λ  ) / _
  ( λ I ) )

(60)

test
         e     /
         λ     =    ΩX

(61)

Frobenius Condition (fork)

H :=
         Y    /
         λ

(62)

test
     (   λ I   )  /
     (  I Y    )  =  H

(63)

test
     (   I λ   )  /
     (    Y I  )  =  H

(64)

The Cartan-Killing form makes H of the Frobenius condition idempotent

test( eval(H,ck)=eval(H/H,ck) )

(65)

And it is unique.

h1:=map(numer,ravel(H-H/H)::List FRAC POLY INT);

h2:=groebner h1

(66)

ck4:=solve(h2,[ε1,εi])

(67)

test( eval(H,ck4.2)=eval(H/H,ck4.1) )

   >> Error detected within library code:
   catdef: division by zero

Handle

Φ :=
         λ     /
         Y

(68)

The Cartan-Killing form makes Φ of the identity

test( eval(Φ,ck)=I )

(69)

and it can be the identity in only this one way.

solve(equate(Φ=I),[ε1,εi])

(70)

If handle is identity then fork is idempotent but the converse is not true

Φ1:=map(numer,ravel(Φ-I)::List FRAC POLY INT);

Φ2:=groebner Φ1

(71)

in?(ideal h2, ideal Φ2)

(72)

in?(ideal Φ2, ideal h2)

(73)

Figure 12

φφ:=          _
  ( Ω  Ω  ) / _
  ( X I I ) / _
  ( I X I ) / _
  ( I I X ) / _
  (  Y  Y );

φφ1:=map((x:ℚ):ℚ+->numer x,φφ)

(74)

φφ2:=denom(ravel(φφ).1)

(75)

test(φφ=(1/φφ2)*φφ1)

(76)

For Cartan-Killing this is just the co-scalar

test(eval(φφ,ck)=eval(Ω,ck))

(77)

test(eval((e,e)/H,ck)=eval(Ω,ck))

(78)

Bi-algebra conditions

ΦΦ:=          _
  (  λ λ  ) / _
  ( I I X ) / _
  ( I X I ) / _
  ( I I X ) / _
  (  Y  Y ) ;

test((e,e)/ΦΦ=φφ)

(79)

test(eval(ΦΦ,ck)=eval(H,ck))

(80)

test(eval(ΦΦ/(d,d),ck)=Ũ)

(81)

test(eval(H/(d,d),ck)=Ũ)

(82)

The Cartan Killing form is a bi-algebra

bi1:=map(numer,ravel(ΦΦ-H)::List FRAC POLY INT);

bi2:=groebner bi1

(83)

b:=solve( equate(ΦΦ=H), [ε1,εi] )

(84)

test(eval(Ų, b.1)=Ũ)

(85)