Edit detail for SandBox Grassmann Algebra Is Frobenius In Many Ways revision 8 of 8

Grassmann Algebra Is Frobenius In Many Ways

A -dimensional vector space represents Grassmann algebra with generators

Linear operators over a 4-dimensional vector space representing Grassmann algebra with two generators.

Ref:

• http://arxiv.org/abs/1103.5113

  -permuted Frobenius Algebras

  Zbigniew Oziewicz (UNAM), Gregory Peter Wene (UTSA)

• http://mat.uab.es/~kock/TQFT.html

  Frobenius algebras and 2D topological quantum field theories

  Joachim Kock

• http://en.wikipedia.org/wiki/Frobenius_algebra
• http://en.wikipedia.org/wiki/Grassmann_algebra

We need the Axiom LinearOperator library.

)library CARTEN ARITY CMONAL CPROP CLOP CALEY

   CartesianTensor is now explicitly exposed in frame initial 
   CartesianTensor will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CARTEN.NRLIB/CARTEN
   Arity is now explicitly exposed in frame initial 
   Arity will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/ARITY.NRLIB/ARITY
   ClosedMonoidal is now explicitly exposed in frame initial 
   ClosedMonoidal will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CMONAL.NRLIB/CMONAL
   ClosedProp is now explicitly exposed in frame initial 
   ClosedProp will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CPROP.NRLIB/CPROP
   ClosedLinearOperator is now explicitly exposed in frame initial 
   ClosedLinearOperator will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CLOP.NRLIB/CLOP
   CaleyDickson is now explicitly exposed in frame initial 
   CaleyDickson will be automatically loaded when needed from 
      /var/aw/var/LatexWiki/CALEY.NRLIB/CALEY

Use the following macros for convenient notation

-- summation
macro Σ(x,i,n)==reduce(+,[x for i in n])

-- list
macro Ξ(f,i,n)==[f for i in n]

-- subscript and superscripts
macro sb == subscript

macro sp == superscript

𝐋 is the domain of 4-dimensional linear operators over the rational functions ℚ (Expression Integer), i.e. ratio of polynomials with integer coefficients.

dim:=4

(1)

macro ℒ == List

macro ℂ == CaleyDickson

macro ℚ == Expression Integer

𝐋 := ClosedLinearOperator(OVAR ['1,'i,'j,'k], ℚ)

(2)

𝐞:ℒ 𝐋      := basisOut()

(3)

𝐝:ℒ 𝐋      := basisIn()

(4)

I:𝐋:=[1]   -- identity for composition

(5)

X:𝐋:=[2,1] -- twist

(6)

V:𝐋:=ev(1) -- evaluation

(7)

Λ:𝐋:=co(1) -- co-evaluation

(8)

equate(eq)==map((x,y)+->(x=y),ravel lhs eq, ravel rhs eq);

Generate structure constants for Grassmann Algebra

The structure constants can be obtained by dividing each matrix entry by the list of basis vectors.

Grassmann algebra will be specified by setting the Caley-Dickson parameters (i2, j2) to zero.

i2:=sp('i,[2])

(9)

j2:=sp('j,[2])

(10)

QQ:=CliffordAlgebra(2,ℚ,matrix [[i2,0],[0,j2]])

(11)

B:ℒ QQ := [monomial(1,[]),monomial(1,[1]),monomial(1,[2]),monomial(1,[1,2])]

(12)

M:Matrix QQ := matrix Ξ(Ξ(B.i*B.j, i,1..dim), j,1..dim)

(13)

S(y) == map(x +-> coefficient(recip(y)*x,[]),M)

ѕ :=map(S,B)::ℒ ℒ ℒ ℚ

Compiling function S with type CliffordAlgebra(2,Expression(Integer)
      ,[[i[;2],0],[0,j[;2]]]) -> Matrix(Expression(Integer))

(14)

-- structure constants form a tensor operator
--Y := Σ(Σ(Σ(ѕ(i)(k)(j)*𝐞.i*𝐝.j*𝐝.k, i,1..dim), j,1..dim), k,1..dim)
Y := eval(Σ(Σ(Σ(ѕ(i)(k)(j)*𝐞.i*𝐝.j*𝐝.k, i,1..dim), j,1..dim), k,1..dim),[i2=0,j2=0])

(15)

matrix Ξ(Ξ((𝐞.i*𝐞.j)/Y, i,1..dim), j,1..dim)

(16)

Units

e:=𝐞.1; i:=𝐞.2; j:=𝐞.3; k:=𝐞.4;

Multiplication of arbitrary Grassmann numbers and

a:=Σ(sb('a,[i])*𝐞.i, i,1..dim)

(17)

b:=Σ(sb('b,[i])*𝐞.i, i,1..dim)

(18)

(a*b)/Y

(19)

Multiplication is Associative

test(
  ( I Y ) / _
  (  Y  ) = _
  ( Y I ) / _
  (  Y  ) )

(20)

A scalar product is denoted by the (2,0)-tensor

U:=Σ(Σ(script('u,[[],[i,j]])*𝐝.i*𝐝.j, i,1..dim), j,1..dim)

(21)

Definition 1

We say that the scalar product is associative if the tensor equation holds:

    Y   =   Y
     U     U

In other words, if the (3,0)-tensor:

(22)

Using the LinearOperator domain in Axiom and some carefully chosen symbols we can easily enter expressions that are both readable and interpreted by Axiom as "graphical calculus" diagrams describing complex products and compositions of linear operators.

ω:𝐋 :=
     (    Y I    )  /
           U        -
     (    I Y    )  /
           U

(23)

Definition 2

An algebra with a non-degenerate associative scalar product is called a [Frobenius Algebra]?.

The Cartan-Killing Trace

Ú:=
   (  Y Λ  ) / _
   (   Y I ) / _
        V

(24)

Ù:=
   (  Λ Y  ) / _
   ( I Y   ) / _
      V

(25)

test(Ù=Ú)

(26)

forms is degenerate

Ũ := Ù

(27)

test
     (    Y I    )  /
           Ũ        =
     (    I Y    )  /
           Ũ

(28)

determinant Ξ(Ξ(retract((𝐞.i * 𝐞.j)/Ũ), j,1..dim), i,1..dim)

(29)

General Solution

We may consider the problem where multiplication Y is given, and look for all associative scalar products

This problem can be solved using linear algebra.

)expose MCALCFN

   MultiVariableCalculusFunctions is now explicitly exposed in frame 
      initial 
J := jacobian(ravel ω,concat map(variables,ravel U)::ℒ Symbol);

nrows(J),ncols(J)

(30)

The matrix J transforms the coefficients of the tensor into coefficients of the tensor . We are looking for the general linear family of tensors such that J transforms into for any such .

If the null space of the J matrix is not empty we can use the basis to find all non-trivial solutions for U:

Ñ:=nullSpace(J)

(31)

ℰ:=map((x,y)+->x=y, concat
       map(variables,ravel U), entries Σ(sb('p,[i])*Ñ.i, i,1..#Ñ) )

(32)

This defines a family of pre-Frobenius algebras:

zero? eval(ω,ℰ)

(33)

Ų:𝐋 := eval(U,ℰ)

(34)

Frobenius Form (co-unit)

d:=ε1*𝐝.1+εi*𝐝.2+εj*𝐝.3+εk*𝐝.4

(35)

𝔇:=equate(d=
    (    e I   ) / _
          Ų    )

Compiling function equate with type Equation(ClosedLinearOperator(
      OrderedVariableList([1,i,j,k]),Expression(Integer))) -> List(
      Equation(Expression(Integer)))

(36)

Express scalar product in terms of Frobenius form

𝔓:=solve(𝔇,Ξ(sb('p,[i]), i,1..#Ñ)).1

(37)

Ų:=eval(Ų,𝔓)

(38)

test
        Y     /
        d     =  Ų

(39)

In general the pairing is not symmetric!

u1:=matrix Ξ(Ξ(retract((𝐞.i 𝐞.j)/Ų), i,1..dim), j,1..dim)

(40)

)set output algebra on
 

)set output tex off

eigenvectors(u1::Matrix FRAC POLY INT)

   (51)
   [
                         4           2     2  2     2  2     3       4
     [eigval = (%B | - εk  - %B ε1 εk  - %B εj  - %B εi  - %B ε1 + %B ),
      eigmult = 1,

         eigvec
       = 
         [
     %B
   [[--],
     εk

     [
                  3           2                2              3
           - εi εk  - %B εj εk  + (- %B ε1 + %B )εi εk - %B εj
         + 
                   2     2       3
           (- %B εi  - %B ε1 + %B )εj
      /
            2     2   2
         (εj  + εi )εk
       ]
     ,

     [
                  3           2                2                 2        3
           - εj εk  + %B εi εk  + (- %B ε1 + %B )εj εk + %B εi εj  + %B εi
         + 
              2       3
           (%B ε1 - %B )εi
      /
            2     2   2
         (εj  + εi )εk
       ]
     ,
    [1]]
           ]
       ]
     ]

)set output algebra off
 

)set output tex on

The scalar product must be non-degenerate:

Ů:=determinant u1

(41)

factor(numer Ů)/factor(denom Ů)

(42)

Frobenius scalar product of "vectors" and

a:=sb('a,[1])*i+sb('a,[2])*j

(43)

b:=sb('b,[1])*i+sb('b,[2])*j

(44)

(a,a)/Ų

(45)

(a,b)/Ų

(46)

Definition 3

Co-scalar product

Solve the Snake Relation as a system of linear equations.

Ω:𝐋:=Σ(Σ(script('u,[[i,j]])*𝐞.i*𝐞.j, i,1..dim), j,1..dim)

(47)

ΩX:=Ω/X;

UXΩ:=(I*ΩX)/(Ų*I);

ΩXU:=(ΩX*I)/(I*Ų);

eq1:=equate(UXΩ=I);

eq2:=equate(ΩXU=I);

snake:=solve(concat(eq1,eq2),concat Ξ(Ξ(script('u,[[i,j]]), i,1..dim), j,1..dim));

if #snake ~= 1 then error "no solution"

Ω:=eval(Ω,snake(1))

(48)

ΩX:=Ω/X;

matrix Ξ(Ξ(retract(Ω/(𝐝.i*𝐝.j)), i,1..dim), j,1..dim)

(49)

Check "dimension" and the snake relations.

O:𝐋:=
       Ω    /
       Ų

(50)

test
    (    I ΩX     )  /
    (     Ų I     )  =  I

(51)

test
    (     ΩX I    )  /
    (    I Ų      )  =  I

(52)

Definition 4

Co-algebra

Compute the "three-point" function and use it to define co-multiplication.

W:=
  (Y I) /
    Ų

(53)

λ:=
  (  ΩX I ΩX  ) /
  (  I  W  I  )

(54)

test
     (    I ΩX     )  /
     (     Y I     )  =  λ

(55)

test
     (     ΩX I    )  /
     (    I  Y     )  =  λ

(56)

Co-associativity

test(
  (  λ  ) / _
  ( I λ ) = _
  (  λ  ) / _
  ( λ I ) )

(57)

test
         e     /
         λ     =    ΩX

(58)

Frobenius Condition (fork)

H :=
         Y    /
         λ

(59)

test
     (   λ I   )  /
     (  I Y    )  =  H

(60)

test
     (   I λ   )  /
     (    Y I  )  =  H

(61)

Handle

Φ :=
         λ     /
         Y

(62)

Figure 12

φφ:=          _
  ( Ω  Ω  ) / _
  ( X I I ) / _
  ( I X I ) / _
  ( I I X ) / _
  (  Y  Y )

(63)

Bi-algebra conditions

ΦΦ:=          _
  (  λ λ  ) / _
  ( I I X ) / _
  ( I X I ) / _
  ( I I X ) / _
  (  Y Y  )

(64)

test((e,e)/ΦΦ=φφ)

(65)

Bi-algebra conditions

ΦΦ:=          _
  (  λ λ  ) / _
  ( I X I ) / _
  (  Y Y  )

(66)

test((e,e)/ΦΦ=φφ)

(67)

Y-forms

Three traces of two graftings of an algebra gives six (2,0)-forms.

Left snail and right snail:

  LS                    RS

  Y /\                    /\ Y
   Y  )                  (  Y
    \/                    \/

  i  j                        j  i
   \/                          \/
    \    /\              /\    /
     e  f  \            /  f  e
      \/    \          /    \/
       \    /          \    /
        f  /            \  f
         \/              \/

LS:=
  ( Y Λ  )/ _
  (  Y I )/ _
      V

(68)

RS:=
  (  Λ Y )/ _
  ( I Y  )/ _
     V

(69)

test(LS=RS)

(70)

Left and right deer:

   RD                 LD

   \ /\/              \/\ /
    Y /\              /\ Y
     Y  )            (  Y
      \/              \/

   i            j    i            j
    \    /\    /      \    /\    /
     \  f  \  /        \  /  f  /
      \/    \/          \/    \/
       \    /\          /\    /
        e  /  \        /  \  e
         \/    \      /    \/
          \    /      \    /
           f  /        \  f
            \/          \/

Left and right deer forms are identical but different from snails.

RD:=
  (  I Λ I  ) / _
  (   Y X   ) / _
  (    Y I  ) / _
        V

(71)

LD:=
  (  I Λ I  ) / _
  (   X Y   ) / _
  (  I Y    ) / _
      V

(72)

test(LD=RD)

(73)

test(RD=RS)

(74)

test(RD=LS)

(75)

Left and right turtles:

  RT                   LT

   /\ / /               \ \ /\
  (  Y /                 \ Y  )
   \  Y                   Y  /
    \/                     \/

           i     j      i     j
    /\    /     /        \     \    /\
   /  f  /     /          \     \  f  \
  /    \/     /            \     \/    \
  \     \    /              \    /     /
   \     e  /                \  e     /
    \     \/                  \/     /
     \    /                    \    /
      \  f                      f  /
       \/                        \/

RT:=
  (  Λ I I ) / _
  ( I Y I  ) / _
  (  I Y   ) / _
      V

(76)

LT:=
  ( I I Λ  ) / _
  (  I Y I ) / _
  (   Y I  ) / _
       V

(77)

test(LT=RT)

(78)

The turles are symmetric

test(RT = X/RT)

(79)

test(LT = X/LT)

(80)

Five of the six forms are independent.

test(RT=RS)

(81)

test(RT=LS)

(82)

test(RT=RD)

(83)

test(LT=RS)

(84)

test(LT=LS)

(85)

test(LT=RD)

(86)