Edit detail for The Algebra of Complex Numbers Is Frobenius In Many Ways revision 8 of 11

The Algebra of Complex Numbers Is Frobenius In Many Ways

Linear operators over a 2-dimensional vector space representing the algebra of complex numbers

Ref:

• http://arxiv.org/abs/1103.5113

  -permuted Frobenius Algebras

  Zbigniew Oziewicz (UNAM), Gregory Peter Wene (UTSA)

• http://mat.uab.es/~kock/TQFT.html

  Frobenius algebras and 2D topological quantum field theories

  Joachim Kock

• http://en.wikipedia.org/wiki/Frobenius_algebra

We need the Axiom LinearOperator? library.

)library CARTEN ARITY CMONAL CPROP CLOP CALEY

   CartesianTensor is now explicitly exposed in frame initial 
   CartesianTensor will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CARTEN.NRLIB/CARTEN
   Arity is now explicitly exposed in frame initial 
   Arity will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/ARITY.NRLIB/ARITY
   ClosedMonoidal is now explicitly exposed in frame initial 
   ClosedMonoidal will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CMONAL.NRLIB/CMONAL
   ClosedProp is now explicitly exposed in frame initial 
   ClosedProp will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CPROP.NRLIB/CPROP
   ClosedLinearOperator is now explicitly exposed in frame initial 
   ClosedLinearOperator will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CLOP.NRLIB/CLOP
   CaleyDickson is now explicitly exposed in frame initial 
   CaleyDickson will be automatically loaded when needed from 
      /var/zope2/var/LatexWiki/CALEY.NRLIB/CALEY

Use the following macros for convenient notation

-- summation
macro Σ(x,i,n)==reduce(+,[x for i in n])

-- list
macro Ξ(f,i,n)==[f for i in n]

-- subscript and superscripts
macro sb == subscript

macro sp == superscript

𝐋 is the domain of 2-dimensional linear operators over the rational functions ℚ (Expression Integer), i.e. ratio of polynomials with integer coefficients.

dim:=2

(1)

macro ℒ == List

macro ℂ == CaleyDickson

macro ℚ == Expression Integer

𝐋 := ClosedLinearOperator(OVAR ['1,'2], ℚ)

(2)

𝐞:ℒ 𝐋      := basisOut()

(3)

𝐝:ℒ 𝐋      := basisIn()

(4)

I:𝐋:=[1]   -- identity for composition

(5)

X:𝐋:=[2,1] -- twist

(6)

V:𝐋:=ev(1) -- evaluation

(7)

Λ:𝐋:=co(1) -- co-evaluation

(8)

equate(eq)==map((x,y)+->(x=y),ravel lhs eq, ravel rhs eq);

Now generate structure constants for Complex Algebra

The basis consists of the real and imaginary units. We use complex multiplication to form the "multiplication table" as a matrix. Then the structure constants can be obtained by dividing each matrix entry by the list of basis vectors.

Split-complex can be specified by Caley-Dickson parameter (q0 = -1)

--q:=1  -- split-complex
q:=sp('i,[2])

(9)

QQ := ℂ(ℚ,'i,q);

Basis: Each B.i is a quaternion number

B:ℒ QQ := map(x +-> hyper x,1$SQMATRIX(dim,ℚ)::ℒ ℒ ℚ)

(10)

-- Multiplication table:
M:Matrix QQ := matrix Ξ(Ξ(B.i*B.j, i,1..dim), j,1..dim)

(11)

-- Function to divide the matrix entries by a basis element
S(y) == map(x +-> real real(x/y),M)

-- The result is a nested list
ѕ :=map(S,B)::ℒ ℒ ℒ ℚ

Compiling function S with type CaleyDickson(Expression(Integer),i,
      *001i(2)) -> Matrix(Expression(Integer))

(12)

-- structure constants form a tensor operator
Y := Σ(Σ(Σ(ѕ(i)(k)(j)*𝐞.i*𝐝.j*𝐝.k, i,1..dim), j,1..dim), k,1..dim)

(13)

arity Y

(14)

matrix Ξ(Ξ((𝐞.i*𝐞.j)/Y, i,1..dim), j,1..dim)

(15)

Multiplication of arbitrary quaternions and

a:=Σ(sb('a,[i])*𝐞.i, i,1..dim)

(16)

b:=Σ(sb('b,[i])*𝐞.i, i,1..dim)

(17)

(a*b)/Y

(18)

Multiplication is Associative

test(
  ( I Y ) / _
  (  Y  ) = _
  ( Y I ) / _
  (  Y  ) )

(19)

A scalar product is denoted by the (2,0)-tensor

U:=Σ(Σ(script('u,[[],[i,j]])*𝐝.i*𝐝.j, i,1..dim), j,1..dim)

(20)

Definition 1

We say that the scalar product is associative if the tensor equation holds:

    Y   =   Y
     U     U

In other words, if the (3,0)-tensor:

(21)

Using the LinearOperator? domain in Axiom and some carefully chosen symbols we can easily enter expressions that are both readable and interpreted by Axiom as "graphical calculus" diagrams describing complex products and compositions of linear operators.

ω:𝐋 :=
     (    Y I    )  /
           U        -
     (    I Y    )  /
           U

(22)

Definition 2

An algebra with a non-degenerate associative scalar product is called a [Frobenius Algebra]?.

The Cartan-Killing Trace

Ú:=
   (  Y Λ  ) / _
   (   Y I ) / _
        V

(23)

Ù:=
   (  Λ Y  ) / _
   ( I Y   ) / _
      V

(24)

test(Ù=Ú)

(25)

forms a non-degenerate associative scalar product for Y

Ũ := Ù

(26)

test
     (    Y I    )  /
           Ũ        =
     (    I Y    )  /
           Ũ

(27)

determinant Ξ(Ξ(retract((𝐞.i * 𝐞.j)/Ũ), j,1..dim), i,1..dim)

(28)

General Solution

We may consider the problem where multiplication Y is given, and look for all associative scalar products

This problem can be solved using linear algebra.

)expose MCALCFN

   MultiVariableCalculusFunctions is now explicitly exposed in frame 
      initial 
J := jacobian(ravel ω,concat map(variables,ravel U)::ℒ Symbol);

u := transpose matrix [concat map(variables,ravel U)::ℒ Symbol];

J::OutputForm * u::OutputForm = 0

(29)

nrows(J),ncols(J)

(30)

The matrix J transforms the coefficients of the tensor into coefficients of the tensor . We are looking for the general linear family of tensors such that J transforms into for any such .

If the null space of the J matrix is not empty we can use the basis to find all non-trivial solutions for U:

Ñ:=nullSpace(J)

(31)

ℰ:=map((x,y)+->x=y, concat
       map(variables,ravel U), entries Σ(sb('p,[i])*Ñ.i, i,1..#Ñ) )

(32)

This defines a family of pre-Frobenius algebras:

zero? eval(ω,ℰ)

(33)

In general the pairing is symmetric!

Ų:𝐋 := eval(U,ℰ)

(34)

matrix Ξ(Ξ((𝐞.i 𝐞.j)/Ų, i,1..dim), j,1..dim)

(35)

This is the most general form of the "dot product" of two quaternions

(a*b)/Ų

(36)

(a*a)/Ų

(37)

Cartan-Killing is a special case

ck:=solve(equate(Ũ=Ų),Ξ(sb('p,[i]), i,1..#Ñ)).1

Compiling function equate with type Equation(ClosedLinearOperator(
      OrderedVariableList([1,2]),Expression(Integer))) -> List(Equation
      (Expression(Integer)))

(38)

The scalar product must be non-degenerate:

Ů:=determinant Ξ(Ξ(retract((𝐞.i * 𝐞.j)/Ų), j,1..dim), i,1..dim)

(39)

factor(numer Ů)/factor(denom Ů)

(40)

Definition 3

Co-pairing

Solve the [Snake Relation]? as a system of linear equations.

Ω:𝐋:=Σ(Σ(script('u,[[i,j]])*𝐞.i*𝐞.j, i,1..dim), j,1..dim)

(41)

d1:=(I*Ω)/(Ų*I);

d2:=(Ω*I)/(I*Ų);

eq1:=equate(d1=I);

eq2:=equate(d2=I);

snake:=solve(concat(eq1,eq2),concat Ξ(Ξ(script('u,[[i,j]]), i,1..dim), j,1..dim));

if #snake ~= 1 then error "no solution"

Ω:=eval(Ω,snake(1))

(42)

matrix Ξ(Ξ(Ω/(𝐝.i*𝐝.j), i,1..dim), j,1..dim)

(43)

Check "dimension" and the snake relations.

d:𝐋:=
       Ω    /
       X    /
       Ų

(44)

test
    (    I Ω     )  /
    (     Ų I    )  =  I

(45)

test
    (     Ω I    )  /
    (    I Ų     )  =  I

(46)

Definition 4

Co-algebra

Compute the "three-point" function and use it to define co-multiplication.

W:=(Y,I)/Ų

(47)

λ:=(Ω,I,Ω)/(I,W,I)

(48)

test
     (    I Ω     )  /
     (     Y I    )  =  λ

(49)

test
     (     Ω I    )  /
     (    I Y     )  =  λ

(50)

Co-associativity

test(
  (  λ  ) / _
  ( I λ ) = _
  (  λ  ) / _
  ( λ I ) )

(51)

Frobenius Condition (fork)

H :=
         Y    /
         λ

(52)

test
     (   λ I   )  /
     (  I Y    )  =  H

(53)

test
     (   I λ   )  /
     (    Y I  )  =  H

(54)

The Cartan-Killing form makes H of the Frobenius condition idempotent

test( eval(H,ck)=eval(H/H,ck) )

(55)

And it is unique.

h1:=map(numer,ravel(H-H/H)::List FRAC POLY INT);

h2:=groebner h1

(56)

ck4:=solve(h2,[p[1],p[2]])

(57)

test( eval(H,ck4.2)=eval(H/H,ck4.2) )

(58)

determinant Ξ(Ξ(retract( (𝐞.i * 𝐞.j)/eval(Ų,ck4.2) ), j,1..dim), i,1..dim)

(59)

Handle

Φ:𝐋 :=
         λ     /
         Y

(60)

The Cartan-Killing form makes Φ of the identity

test( eval(Φ,ck)=I )

(61)

and it can be the identity in only this one way.

solve(equate(Φ=I),[p[1],p[2]])

(62)

If handle is identity then fork is idempotent but the converse is not true

Φ1:=map(numer,ravel(Φ-I)::List FRAC POLY INT);

Φ2:=groebner Φ1

(63)

in?(ideal h2, ideal Φ2)

(64)

in?(ideal Φ2, ideal h2)

(65)

Bi-algebra conditions

ΦΦ:=         _
  (  λ λ  ) / _
  ( I X I ) / _
  (  Y Y  );

test( H/H = ΦΦ )

(66)

The Cartan Killing form is a bi-algebra

bi1:=map(numer,ravel(ΦΦ-H)::List FRAC POLY INT);

bi2:=groebner bi1

(67)

b:=solve( equate(ΦΦ=H), [sb('p,[i]) for i in 1..#Ñ] )

(68)

test(eval(Ų, b.1)=Ũ)

(69)

Scalars for figure 12 (only 1 non-zero for Cartan-Killing form)

φφ:=          _
  (  Ω Ω  ) / _
  ( I X I ) / _
  (  Y Y  );

φφ1:=map((x:ℚ):ℚ+->numer x,φφ)

(70)

φφ2:=denom(ravel(φφ).1)

(71)

test(φφ=(1/φφ2)*φφ1)

(72)

eval(φφ,ck)

(73)

Definition 5

i = Unit of the algebra

i:=𝐞.1

(74)

test
         i     /
         λ     =    Ω

(75)

Co-unit

i 
U

ι:𝐋:=
    (    i I   ) /
          Ų

(76)

Y=U
ι  

test
        Y     /
        ι     =  Ų

(77)

For example:

ex1:=[q=1,p[1]=0,p[2]=1]

(78)

Ų0:𝐋  :=eval(Ų,ex1)

(79)

Ω0:𝐋  :=eval(Ω,ex1)$𝐋

(80)

λ0:𝐋  :=eval(λ,ex1)$𝐋

(81)

Φ0:𝐋 :=eval(Φ,ex1)$𝐋

(82)